Tutorial DS1307 Tiny RTC con Arduino

Mar 20, 2015 | Tutoriales Arduino | 32 comments

El DS1307 de Maxim/Dallas es un circuito integrado reloj en tiempo real (RTC) capaz de almacenar y llevar la cuenta de la fecha y hora de manera autónoma, además disponemos de unos cuantos bytes de memoria RAM no volátil (NVRAM) para almacenar datos arbitrarios.

En esta entrada, exploraremos las ventajas y operaciones básicas del circuito DS1307 instalado en el módulo TinyRTC, también explicaremos su funcionamiento en conjunto con una placa arduino para aquellas aplicaciones que requieren un control preciso del tiempo.

El módulo Tiny RTC, además de todo el circuito de soporte para el DS1307, incluye también una memoria EEPROM I2C para almacenar datos en ella y un zócalo para soldar de manera opcional un sensor de temperatura DS18B20 (one-wire), sin embargo en esta ocasión trataremos únicamente el uso del DS1307; el uso de la memoria EEPROM y el sensor quedarán de tarea para el lector.

El arduino posee un CPU bastante poderoso, y sin embargo aún así es incapaz de mantener la hora correctamente a largo plazo, debido a los microsegundos que se atrasan (o adelantan) al dividir la frecuencia del reloj principal para dar con el segundo exacto. Por esta razón tanto el arduino como nuestra PC requieren de un circuito integrado especializado que incluye un oscilador a cristal de cuarzo. Dicho oscilador genera una frecuencia estable y divisible mediante hardware digital para lograr el segundo exacto. Este circuito integrado especializado normalmente también tiene la capacidad de funcionar en un modo de bajo consumo que permite alimentarlo con una batería pequeña (del tipo que llevan los relojes).

Conceptos básicos.

Para entender como funciona el circuito DS1307 y el programa que corre en la tarjeta Arduino debemos conocer algunos conceptos clave:

RTC o Reloj en Tiempo Real – Es un circuito electrónico especializado cuya función es mantener la hora y fecha actual en un sistema informático (ya sea con microcontrolador u otro tipo de CPU). Se caracteríza por tener un bajo consumo de energía y también normalmente su propia fuente de alimentación auxiliar. Al recurrir a este tipo de circuitos integrados es de esperar que se obtenga una mejor precisión en la cuenta del tiempo. Un ejemplo de dispositivos que incluyen relojes en tiempo real son las computadoras personales (PC).
Bus I2C o TWI – Es el protocolo de comunicación físico mediante el cual se comunican el Arduino y el módulo RTC DS1307. El bus cuenta con dos lineas: de datos y de reloj, ambas del tipo colector abierto (o drenador abierto). Por lo que se requieren resistencias pull-up (Rpu en el esquemático) para generar un estado lógico alto. Más abajo en esta página se muestra una conexión básica del DS1307 con un microcontrolador a través del bus I2C.
Decimal codificado en binario – Es un estándar de datos en el cual los dígitos decimales se representan mediante secuencias de 4 bits. Esto es así por que con 4 bits se pueden representar todos los dígitos decimales del 0 al 9. En un byte en memoria se pueden almacenar números decimales del 0 al 99. En el DS1307 los datos de fecha y hora están codificados en BCD y veremos más adelante la forma de convertir de BCD a binario. A continuación se muestran los dígitos decimales y sus equivalentes en BCD.

Recomendamos ampliar nuestra lectura sobre estos temas para poder comprender como funciona el reloj en tiempo real DS1307 y poder solucionar cualquier problema durante las prácticas que realicemos.

Funcionamiento interno y registros del DS1307

Para la comunicación a través de I2C, el DS1307 requiere de dos resistencias pull-up en los pines SDA y SCL. Si vamos a utilizar el pin SQW/OUT, este también requiere una resistencia pull-up para funcionar correctamente.
El DS1307 requiere un cristal de 32.768 Khz, este valor viene dado por el hecho de que 2^15 = 32,768. Esto quiere decir que la frecuencia es divisible binariamente para generar un segundo exacto. El cristal ya se incluye si compramos algún módulo con el DS1307.
El DS1307 requiere dos fuentes de alimentación: Por una parte, requiere alimentación de 5 volts que opera mientras el circuito esta encendido y funcionando y otra fuente de poder que proviene de una batería de litio (tipo reloj) que mantiene funcionando el reloj/calendario mientras la alimentación principal NO esta disponible. El cambio entre ambas fuentes de alimentación es gestionado por el DS1307 de manera automática.
Disponemos de un pin de salida que puede ser configurado para que el RTC entregue una onda cuadrada con una frecuencia configurable, las frecuencias disponibles se muestran en la siguiente tabla y se configuran mediante los bits RS1, RS0 y SQWE de registro de control, si se usa este pin hay que agregar una resistencia pull-up, ya que es del tipo “Open drain”:
Los registros del DS1307 almacenan la fecha y la hora en formato BCD. La dirección de cada registro y la información almacenada en cada uno se muestra en la siguiente tabla:
El funcionaliento del chip se controla mediante el bit 7 del registro del segundero (0x00) y el registro de control (0x07): El bit CH del segundero detiene el reloj cuando esta en alto (así se entregan los módulos de fábrica) y en este modo NO se lleva el conteo de tiempo por que el oscilador esta detenido. ES MUY IMPORTANTE PONER A 0 ESTE BIT PARA QUE EL RTC FUNCIONE (ver código de ejemplo). El registro de control maneja la funcionalidad del pin de salida de onda cuadrada.
A partir de la dirección 0x08 disponemos de memoria RAM no volátil (NVRAM) cuyo contenido no se borra con la pérdida de energía, este segmento de memoria funciona de manera similar a una memoria EEPROM, solo que no existen limitaciones en cuanto al numero de escrituras.

Materiales necesarios.

Para las prácticas vamos a requerir el siguiente material, que pueden encontrar en nuestra tienda virtual:

Conexión del TinyRTC al Arduino

El módulo TinyRTC requiere las siguientes conexiones con la tarjeta Arduino. Nótese que el pin “DS” del módulo TinyRTC no se utiliza, corresponde al sensor de temperatura 1-wire que no se encuentra instalado de fábrica. Solamente son indispensables las lineas SDA, SCL y la alimentación de 5 volts:

Para montar el circuito de prueba, podemos auxiliarnos de un protoboard, de manera opcional. También es válido usar solamente cables.El circuito armado nos quedó de la siguiente forma:

Ejemplo de lectura DS1307 sin librería

Con la información que tenemos hasta ahora, ya podemos darnos una idea de como estructurar el sketch para leer y escribir el RTC DS1307. Utilizaremos la librería “Wire.h” que se incluye instalada de serie con el ambiente arduino para manejar la comunicación I2C entre el DS1307 y el Arduino. Presentamos dos “sketches” o programas. En el primero realizaremos la escritura o puesta a tiempo del módulo RTC y en el segundo, realizaremos la lectura y muestra de la información de fecha y hora que ya hemos almacenado. En estos ejemplos NO estamos utilizando ninguna librería específica para el DS1307, solamente utilizamos la librería “Wire.h” de arduino para hablar con dispositivos a través del bus I2C.

¿Como poner a tiempo el DS1307?

El siguiente código permite escribir una fecha arbitraria en el RTC y ponerlo a funcionar. Hay que configurar una fecha y hora válidos (actual) dentro de la función setup, donde se inicializan los valores de variables que contienen información horaria. Hay que aclarar que se trata de un ejemplo minimalista que será fácil de entender para los principiantes.

/**
   GeekFactory - "INNOVATING TOGETHER"
   Distribucion de materiales para el desarrollo e innovacion tecnologica
   www.geekfactory.mx
   Ejemplo para arduino de escritura de fecha y hora al DS1307 en el
   modulo TinyRTC. Este ejemplo pone a tiempo el reloj con los datos
   provistos en la funcion setup.
*/
#include <Wire.h>
// Declaracion de las variables para almacenar informacion de tiempo
uint8_t second, minute, hour, wday, day, month, year;
/**
   Inicio del sketch: Este codigo se ejecuta al conectar el arduino
*/
void setup() {
  // NOTA: Estas sentencias se requieren para alimentar directamente el
  // chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre
  // la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).
  // Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas
  pinMode(A3, OUTPUT);
  digitalWrite(A3, HIGH);
  pinMode(A2, OUTPUT);
  digitalWrite(A2, LOW);
  // Configurar la comunicacion a 9600 baudios
  Serial.begin(9600);
  // Preparar la librería Wire (I2C)
  Wire.begin();
  // Imprimir encabezado a la terminal
  Serial.println("----------------------------------------------------");
  Serial.println(" EJEMPLO ESCRITURA DE DS1307 EN TINYRTC CON ARDUINO ");
  Serial.println("            https://www.geekfactory.mx               ");
  Serial.println("----------------------------------------------------");
  // Inicializar las variables con el tiempo a cargar en el modulo RTC
  // ¡¡¡ COLOCA AQUI LA FECHA Y HORA QUE QUIERAS GRABAR EN EL RTC !!!
  second = 30;
  minute = 30;
  hour = 20;
  wday = 4;
  day = 1;
  month = 1;
  year = 15;
}
/**
   Ciclo principàl del sketch: Escribir informacion de fecha y hora una sola vez
*/
void loop() {
  // Escribir hora y fecha al RTC
  write_ds1307();
  // Imprimimos la fecha y hora
  Serial.println("Poner a tiempo el DS1307 en Tiny RTC:");
  print_time();
  // Ciclo infinito, no hacemos nada mas
  for (;;);
}
/**
   Esta funcion establece la cominicación con el DS1307 y escribe los registros
   de fecha y hora. Utiliza la información provista en la función setup que debes
   modificar con la fecha y hora actuales
*/
bool write_ds1307()
{
  // Iniciar el intercambio de información con el DS1307 (0x68)
  Wire.beginTransmission(0x68);
  // Escribir la dirección del registro segundero
  Wire.write(0x00);
  // Escribir valores en los registros, nos aseguramos que el bit clock halt
  // en el registro del segundero este desactivado (esto hace que el reloj funcione)
  Wire.write(bin2bcd(second & 0x7F)); // <--- Esto hace que el reloj comience a trabajar
  Wire.write(bin2bcd(minute));
  Wire.write(bin2bcd(hour));
  Wire.write(bin2bcd(wday));
  Wire.write(bin2bcd(day));
  Wire.write(bin2bcd(month));
  Wire.write(bin2bcd(year));
  // Terminamos la escritura y verificamos si el DS1307 respondio
  // Si la escritura se llevo a cabo el metodo endTransmission retorna 0
  if (Wire.endTransmission() != 0)
    return false;
  // Retornar verdadero si se escribio con exito
  return true;
}
/**
   Convierte un numero binario a BCD
*/
uint8_t bin2bcd(uint8_t bin)
{
  return (bin / 10 * 16) + (bin % 10);
}
/**
   Imprime la fecha y hora al monitor serial de arduino
*/
void print_time()
{
  Serial.print("Fecha: ");
  Serial.print(day);
  Serial.print('/');
  Serial.print(month);
  Serial.print('/');
  Serial.print(year);
  Serial.print("  Hora: ");
  Serial.print(hour);
  Serial.print(':');
  Serial.print(minute);
  Serial.print(':');
  Serial.print(second);
  Serial.println();
}

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

/**

GeekFactory - "INNOVATING TOGETHER"

Distribucion de materiales para el desarrollo e innovacion tecnologica

www.geekfactory.mx

Ejemplo para arduino de escritura de fecha y hora al DS1307 en el

modulo TinyRTC. Este ejemplo pone a tiempo el reloj con los datos

provistos en la funcion setup.

#include <Wire.h>

// Declaracion de las variables para almacenar informacion de tiempo

uint8_t second, minute, hour, wday, day, month, year;

/**

Inicio del sketch: Este codigo se ejecuta al conectar el arduino

void setup() {

// NOTA: Estas sentencias se requieren para alimentar directamente el

// chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre

// la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).

// Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas

pinMode(A3, OUTPUT);

digitalWrite(A3, HIGH);

pinMode(A2, OUTPUT);

digitalWrite(A2, LOW);

// Configurar la comunicacion a 9600 baudios

Serial.begin(9600);

// Preparar la librería Wire (I2C)

Wire.begin();

// Imprimir encabezado a la terminal

Serial.println("----------------------------------------------------");

Serial.println(" EJEMPLO ESCRITURA DE DS1307 EN TINYRTC CON ARDUINO ");

Serial.println(" https://www.geekfactory.mx ");

Serial.println("----------------------------------------------------");

// Inicializar las variables con el tiempo a cargar en el modulo RTC

// ¡¡¡ COLOCA AQUI LA FECHA Y HORA QUE QUIERAS GRABAR EN EL RTC !!!

second = 30;

minute = 30;

hour = 20;

wday = 4;

day = 1;

month = 1;

year = 15;

}

/**

Ciclo principàl del sketch: Escribir informacion de fecha y hora una sola vez

void loop() {

// Escribir hora y fecha al RTC

write_ds1307();

// Imprimimos la fecha y hora

Serial.println("Poner a tiempo el DS1307 en Tiny RTC:");

print_time();

// Ciclo infinito, no hacemos nada mas

for (;;);

}

/**

Esta funcion establece la cominicación con el DS1307 y escribe los registros

de fecha y hora. Utiliza la información provista en la función setup que debes

modificar con la fecha y hora actuales

bool write_ds1307()

{

// Iniciar el intercambio de información con el DS1307 (0x68)

Wire.beginTransmission(0x68);

// Escribir la dirección del registro segundero

Wire.write(0x00);

// Escribir valores en los registros, nos aseguramos que el bit clock halt

// en el registro del segundero este desactivado (esto hace que el reloj funcione)

Wire.write(bin2bcd(second & 0x7F)); // <--- Esto hace que el reloj comience a trabajar

Wire.write(bin2bcd(minute));

Wire.write(bin2bcd(hour));

Wire.write(bin2bcd(wday));

Wire.write(bin2bcd(day));

Wire.write(bin2bcd(month));

Wire.write(bin2bcd(year));

// Terminamos la escritura y verificamos si el DS1307 respondio

// Si la escritura se llevo a cabo el metodo endTransmission retorna 0

if (Wire.endTransmission() != 0)

return false;

// Retornar verdadero si se escribio con exito

return true;

}

/**

Convierte un numero binario a BCD

uint8_t bin2bcd(uint8_t bin)

{

return (bin / 10 * 16) + (bin % 10);

}

/**

Imprime la fecha y hora al monitor serial de arduino

void print_time()

{

Serial.print("Fecha: ");

Serial.print(day);

Serial.print('/');

Serial.print(month);

Serial.print('/');

Serial.print(year);

Serial.print(" Hora: ");

Serial.print(hour);

Serial.print(':');

Serial.print(minute);

Serial.print(':');

Serial.print(second);

Serial.println();

}

El resultado de ejecutar el sketch anterior en el DS1307 debe ser como el siguiente:

Este programa no genera salida adicional a la terminal serial, ya que solamente pone a tiempo el reloj. Una vez puesto a tiempo ya podemos usar la información almacenada con nuestro siguiente sketch o para la aplicación que estamos desarrollando. Recomendamos ejecutar este sketch solamente una vez, ya que siempre que se resetea o conecta la tarjeta este reestablecerá la misma fecha y hora programadas, es necesario cargar el sketch de lectura de inmediato y evitar reiniciar la tarjeta con este sketch cargado.

¿Como leer la fecha y hora del DS1307?

El siguiente sketch lee la información de fecha y hora del DS1307 y la muestra en la terminal (monitor serial).

/**
   GeekFactory - "INNOVATING TOGETHER"
   Distribucion de materiales para el desarrollo e innovacion tecnologica
   www.geekfactory.mx
   Ejemplo para arduino de lectura de fecha y hora al DS1307 en el
   modulo TinyRTC. Este ejemplo envia al monitor serial la fecha y la hora
   almacenada en el RTC cada segundo.
*/
#include <Wire.h>
// Declaracion de las variables para almacenar informacion de tiempo leida desde RTC
uint8_t second, minute, hour, wday, day, month, year, ctrl;
/**
   Inicio del sketch: Este codigo se ejecuta al conectar el arduino
*/
void setup() {
  // NOTA: Estas sentencias se requieren para alimentar directamente el
  // chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre
  // la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).
  // Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas
  pinMode(A3, OUTPUT);
  digitalWrite(A3, HIGH);
  pinMode(A2, OUTPUT);
  digitalWrite(A2, LOW);
  // Configurar la comunicacion a 9600 baudios
  Serial.begin(9600);
  // Preparar la librería Wire (I2C)
  Wire.begin();
  // Imprimir encabezado a la terminal
  Serial.println("----------------------------------------------------");
  Serial.println("EJEMPLO LECTURA DE RTC DS1307 EN TINYRTC CON ARDUINO");
  Serial.println("            https://www.geekfactory.mx               ");
  Serial.println("----------------------------------------------------");
}
/**
   Ciclo principàl del sketch: Leer y mostrar la hora y fecha cada segundo
*/
void loop() {
  // Esperar 1 segundo
  delay(1000);
  // Leer los registros del RTC
  if (read_ds1307()) {
    // Mostrar la fecha y hora
    print_time();
  } else {
    // No se puede leer desde le DS1307 (NACK en I2C)
    Serial.println("No se detecta el DS1307, revisar conexiones");
  }
}
/**
   Esta funcion establece la cominicación con el DS1307 y lee los registros
   de fecha y hora. Entrega la informacion horaria en las variables globales
   declaradas al principio del sketch.
*/
bool read_ds1307()
{
  // Iniciar el intercambio de información con el DS1307 (0xD0)
  Wire.beginTransmission(0x68);
  // Escribir la dirección del segundero
  Wire.write(0x00);
  // Terminamos la escritura y verificamos si el DS1307 respondio
  // Si la escritura se llevo a cabo el metodo endTransmission retorna 0
  if (Wire.endTransmission() != 0)
    return false;
  // Si el DS1307 esta presente, comenzar la lectura de 8 bytes
  Wire.requestFrom(0x68, 8);
  // Recibimos el byte del registro 0x00 y lo convertimos a binario
  second = bcd2bin(Wire.read());
  minute = bcd2bin(Wire.read()); // Continuamos recibiendo cada uno de los registros
  hour = bcd2bin(Wire.read());
  wday = bcd2bin(Wire.read());
  day = bcd2bin(Wire.read());
  month = bcd2bin(Wire.read());
  year = bcd2bin(Wire.read());
  // Recibir los datos del registro de control en la dirección 0x07
  ctrl = Wire.read();
  // Operacion satisfactoria, retornamos verdadero
  return true;
}
/**
   Esta función convierte un número BCD a binario. Al dividir el número guardado
   en el parametro BCD entre 16 y multiplicar por 10 se convierten las decenas
   y al obtener el módulo 16 obtenemos las unidades. Ambas cantidades se suman
   para obtener el valor binario.
*/
uint8_t bcd2bin(uint8_t bcd)
{
  // Convertir decenas y luego unidades a un numero binario
  return (bcd / 16 * 10) + (bcd % 16);
}
/**
   Imprime la fecha y hora al monitor serial de arduino
*/
void print_time()
{
  Serial.print("Fecha: ");
  Serial.print(day);
  Serial.print('/');
  Serial.print(month);
  Serial.print('/');
  Serial.print(year);
  Serial.print("  Hora: ");
  Serial.print(hour);
  Serial.print(':');
  Serial.print(minute);
  Serial.print(':');
  Serial.print(second);
  Serial.println();
}

100

101

102

103

104

105

106

107

108

109

110

111

112

113

114

115

116

117

118

119

120

121

122

123

124

125

126

127

128

/**

GeekFactory - "INNOVATING TOGETHER"

Distribucion de materiales para el desarrollo e innovacion tecnologica

www.geekfactory.mx

Ejemplo para arduino de lectura de fecha y hora al DS1307 en el

modulo TinyRTC. Este ejemplo envia al monitor serial la fecha y la hora

almacenada en el RTC cada segundo.

#include <Wire.h>

// Declaracion de las variables para almacenar informacion de tiempo leida desde RTC

uint8_t second, minute, hour, wday, day, month, year, ctrl;

/**

Inicio del sketch: Este codigo se ejecuta al conectar el arduino

void setup() {

// NOTA: Estas sentencias se requieren para alimentar directamente el

// chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre

// la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).

// Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas

pinMode(A3, OUTPUT);

digitalWrite(A3, HIGH);

pinMode(A2, OUTPUT);

digitalWrite(A2, LOW);

// Configurar la comunicacion a 9600 baudios

Serial.begin(9600);

// Preparar la librería Wire (I2C)

Wire.begin();

// Imprimir encabezado a la terminal

Serial.println("----------------------------------------------------");

Serial.println("EJEMPLO LECTURA DE RTC DS1307 EN TINYRTC CON ARDUINO");

Serial.println(" https://www.geekfactory.mx ");

Serial.println("----------------------------------------------------");

}

/**

Ciclo principàl del sketch: Leer y mostrar la hora y fecha cada segundo

void loop() {

// Esperar 1 segundo

delay(1000);

// Leer los registros del RTC

if (read_ds1307()) {

// Mostrar la fecha y hora

print_time();

} else {

// No se puede leer desde le DS1307 (NACK en I2C)

Serial.println("No se detecta el DS1307, revisar conexiones");

}

/**

Esta funcion establece la cominicación con el DS1307 y lee los registros

de fecha y hora. Entrega la informacion horaria en las variables globales

declaradas al principio del sketch.

bool read_ds1307()

{

// Iniciar el intercambio de información con el DS1307 (0xD0)

Wire.beginTransmission(0x68);

// Escribir la dirección del segundero

Wire.write(0x00);

// Terminamos la escritura y verificamos si el DS1307 respondio

// Si la escritura se llevo a cabo el metodo endTransmission retorna 0

if (Wire.endTransmission() != 0)

return false;

// Si el DS1307 esta presente, comenzar la lectura de 8 bytes

Wire.requestFrom(0x68, 8);

// Recibimos el byte del registro 0x00 y lo convertimos a binario

second = bcd2bin(Wire.read());

minute = bcd2bin(Wire.read()); // Continuamos recibiendo cada uno de los registros

hour = bcd2bin(Wire.read());

wday = bcd2bin(Wire.read());

day = bcd2bin(Wire.read());

month = bcd2bin(Wire.read());

year = bcd2bin(Wire.read());

// Recibir los datos del registro de control en la dirección 0x07

ctrl = Wire.read();

// Operacion satisfactoria, retornamos verdadero

return true;

}

/**

Esta función convierte un número BCD a binario. Al dividir el número guardado

en el parametro BCD entre 16 y multiplicar por 10 se convierten las decenas

y al obtener el módulo 16 obtenemos las unidades. Ambas cantidades se suman

para obtener el valor binario.

uint8_t bcd2bin(uint8_t bcd)

{

// Convertir decenas y luego unidades a un numero binario

return (bcd / 16 * 10) + (bcd % 16);

}

/**

Imprime la fecha y hora al monitor serial de arduino

void print_time()

{

Serial.print("Fecha: ");

Serial.print(day);

Serial.print('/');

Serial.print(month);

Serial.print('/');

Serial.print(year);

Serial.print(" Hora: ");

Serial.print(hour);

Serial.print(':');

Serial.print(minute);

Serial.print(':');

Serial.print(second);

Serial.println();

}

El resultado de este programa es el siguiente, deberemos ver la fecha y la hora en el monitor serial, esta debe conservarse aunque desconectemos el cable USB o la alimentación principal del Arduino.

Librería de Arduino para el DS1307

La librería para el DS1307 encapsula el código anterior en una clase cuyos métodos podemos llamar para obtener la fecha y hora o poner a tiempo el reloj. Usando una librería, nuestro programa principal puede reducirse bastante, además de que queda más legible y elegante. En el ejemplo siguiente vamos a ver como realizar la operación de lectura, pero esta vez haciendo uso de la librería DS1307RTC.

Para que el siguiente código funcione, es necesario descargar e instalar dos librerías en nuestro entorno de arduino:

Librería DS1307RTC – Esta librería permite leer y escribir el reloj DS1307
Librería TimeLib – Permite realizar operaciones de fecha y hora en formato unix (solo se usa para compilar la libreria DS1307RTC, no forma parte de los ejemplos).

En la carpeta de ejemplos de la librería DS1307RTC podemos encontrar también el ejemplo para poner a tiempo el reloj con una fecha y hora arbitrarias.

/**
   GeekFactory - "INNOVATING TOGETHER"
   Distribucion de materiales para el desarrollo e innovacion tecnologica
   www.geekfactory.mx
   Ejemplo de libreria DS1307RTC para lectura del valor fecha y hora almacenado.
   Requiere el reloj en tiempo real (RTC) DS1307 conectado en el bus I2C.
   Requiere la instalacion de la libreria DS1307RTC para manejo del chip RTC.
   Requiere la instalacion de la libreria TimeLib con funciones de manejo de fechas.
*/
#include <Wire.h>
#include <TimeLib.h>
#include <DS1307RTC.h>
void setup() {
  // NOTA: Estas sentencias se requieren para alimentar directamente el
  // chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre
  // la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).
  // Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas
  pinMode(A3, OUTPUT);
  digitalWrite(A3, HIGH);
  pinMode(A2, OUTPUT);
  digitalWrite(A2, LOW);
  // Configurar la comunicacion a 9600 baudios
  Serial.begin(9600);
  // Mostrar la leyenda inicial
  // Imprimir encabezado a la terminal
  Serial.println(F("----------------------------------------------------"));
  Serial.println(F("EJEMPLO LECTURA DE RTC DS1307 EN TINYRTC CON ARDUINO"));
  Serial.println(F("            https://www.geekfactory.mx               "));
  Serial.println(F("----------------------------------------------------"));
}
void loop() {
  // Declaramos una estructura "tm" llamada datetime para almacenar
  // La fecha y la hora actual obtenida desde el chip RTC.
  tmElements_t datetime;
  // Obtener la fecha y hora desde el chip RTC
  if (RTC.read(datetime)) {
    // Comenzamos a imprimir la informacion
    Serial.print(F("OK, Time = "));
    print2digits(datetime.Hour);
    Serial.write(':');
    print2digits(datetime.Minute);
    Serial.write(':');
    print2digits(datetime.Second);
    Serial.print(F(", Date (D/M/Y) = "));
    Serial.print(datetime.Day);
    Serial.write('/');
    Serial.print(datetime.Month);
    Serial.write('/');
    Serial.print(tmYearToCalendar(datetime.Year));
    Serial.println();
    delay(1000);
  }
  else {
    if (RTC.chipPresent()) {
      // El reloj esta detenido, es necesario ponerlo a tiempo
      Serial.println(F("EL DS1307 ESTA DETENIDO"));
      Serial.println(F("CORRE EL PROGRAMA PARA PONERLO A TIEMPO"));
    }
    else {
      // No se puede comunicar con el RTC en el bus I2C, revisar las conexiones.
      Serial.println(F("NO SE DETECTO EL DS1307"));
      Serial.println(F("REVISA TUS CONEXIONES E INTENTA DE NUEVO"));
    }
    // Esperamos indefinidamente
    for (;;);
  }
}
/**
   Funcion auxiliar para imprimir siempre 2 digitos
*/
void print2digits(int number) {
  if (number >= 0 && number < 10) {
    Serial.write('0');
  }
  Serial.print(number);
}

/**

GeekFactory - "INNOVATING TOGETHER"

Distribucion de materiales para el desarrollo e innovacion tecnologica

www.geekfactory.mx

Ejemplo de libreria DS1307RTC para lectura del valor fecha y hora almacenado.

Requiere el reloj en tiempo real (RTC) DS1307 conectado en el bus I2C.

Requiere la instalacion de la libreria DS1307RTC para manejo del chip RTC.

Requiere la instalacion de la libreria TimeLib con funciones de manejo de fechas.

#include <Wire.h>

#include <TimeLib.h>

#include <DS1307RTC.h>

void setup() {

// NOTA: Estas sentencias se requieren para alimentar directamente el

// chip RTC desde los pines A3 Y A2 (colocar directamente el modulo sobre

// la tarjeta arduino, sin la necesidad de cablear en Arduino UNO).

// Si no se quiere hacer esto, se pueden eliminar o comentar sin problemas

pinMode(A3, OUTPUT);

digitalWrite(A3, HIGH);

pinMode(A2, OUTPUT);

digitalWrite(A2, LOW);

// Configurar la comunicacion a 9600 baudios

Serial.begin(9600);

// Mostrar la leyenda inicial

// Imprimir encabezado a la terminal

Serial.println(F("----------------------------------------------------"));

Serial.println(F("EJEMPLO LECTURA DE RTC DS1307 EN TINYRTC CON ARDUINO"));

Serial.println(F(" https://www.geekfactory.mx "));

Serial.println(F("----------------------------------------------------"));

}

void loop() {

// Declaramos una estructura "tm" llamada datetime para almacenar

// La fecha y la hora actual obtenida desde el chip RTC.

tmElements_t datetime;

// Obtener la fecha y hora desde el chip RTC

if (RTC.read(datetime)) {

// Comenzamos a imprimir la informacion

Serial.print(F("OK, Time = "));

print2digits(datetime.Hour);

Serial.write(':');

print2digits(datetime.Minute);

Serial.write(':');

print2digits(datetime.Second);

Serial.print(F(", Date (D/M/Y) = "));

Serial.print(datetime.Day);

Serial.write('/');

Serial.print(datetime.Month);

Serial.write('/');

Serial.print(tmYearToCalendar(datetime.Year));

Serial.println();

delay(1000);

}

else {

if (RTC.chipPresent()) {

// El reloj esta detenido, es necesario ponerlo a tiempo

Serial.println(F("EL DS1307 ESTA DETENIDO"));

Serial.println(F("CORRE EL PROGRAMA PARA PONERLO A TIEMPO"));

}

else {

// No se puede comunicar con el RTC en el bus I2C, revisar las conexiones.

Serial.println(F("NO SE DETECTO EL DS1307"));

Serial.println(F("REVISA TUS CONEXIONES E INTENTA DE NUEVO"));

}

// Esperamos indefinidamente

for (;;);

}

/**

Funcion auxiliar para imprimir siempre 2 digitos

void print2digits(int number) {

if (number >= 0 && number < 10) {

Serial.write('0');

}

Serial.print(number);

}

El resultado de ejecutar el ejemplo anterior debe ser similar al siguiente:

Programación de un horario con Arduino

En esta entrada te enseñamos lo básico sobre el funcionamiento del reloj en tiempo real DS1307. Sin embargo hasta ahora solo puedes leer o escribir la fecha / hora. Si deseas aprender a realizar acciones concretas en una fecha y hora determinadas, será necesario que continues estudiando nuestro siguiente tutorial que trata el tema de la programación de eventos y horarios con el Arduino y un RTC. Puedes encontrar el tutorial avanzado del RTC en el siguiente enlace:

Tutorial avanzado de programación de horarios con Arduino y RTC

Con este tutorial puedes realizar el control de cargas de corriente alterna, como lámparas y ventiladores, aunque en realidad puedes controlar muchas otras cosas a través de las librerías disponibles para arduino. Te invitamos a continuar aprendiendo sobre el tema.

Conclusión

En este tutorial aprendimos como manipular los registros del DS1307 para ponerlo a tiempo y para realizar la lectura de la fecha y hora. Aprendimos que es posible accesar al DS1307 mediante librerías especializadas o de forma manual mediante la librería “wire.h” sin necesidad de instalar ninguna otra librería. La forma final en la que el usuario accede a los datos del RTC depende de sus preferencias y del proyecto en el que se trabaja. El DS1307 es un ejemplo muy bueno de como podernos comunicarnos con cualquier dispositivo usando el bus I2C, por lo que siempre podemos utilizar este código como base para cualquier dispositivo que posee interfaz I2C.

32 Comments

← Older Comments

Raúl on 27 junio, 2020 at 10:29
Hola, he usado el código para configurar la hora y parece que todo lo hace correctamente puesto que no me da ningún error y en la consola aparece la hora y todo correctamente, pero cuando uso el código para leer la hora me dice que no se detecta el ds1307 que compruebe las conexiones, no tengo manera de comprobarlas, pero si el código de configurar la hora no da error debería de estar funcionando verdad? Gracias de antemano 🙂
Reply
Chema on 22 febrero, 2020 at 17:50
#include
#include
#include
#include
#include
#include
#include
using namespace std;
RTC_DS3231 rtc;
MatrizLed pantalla;
void setup() {
pantalla.begin(12, 11, 10, 4);
pantalla.setIntensidad(1);
pantalla.rotar(false);
Serial.begin(57600);
pinMode(A3, OUTPUT);
digitalWrite(A3, HIGH);
pinMode(A2, OUTPUT);
digitalWrite(A2, LOW);
}
void loop() {
tmElements_t datetime;
RTC.read(datetime);
String seguna;
String segunh;
String hora = String(datetime.Hour);
String segun = String(datetime.Minute);
if (segun.length() == 1 ) {
seguna = “0” + segun;
} else {
seguna = segun;
}
if (hora.length() == 1 ) {
segunh = ” ” + hora;
} else {
segunh = hora;
}
Serial.print (segunh[0]);
Serial.print (segunh[1]);
Serial.println();
pantalla.escribirCaracter(segunh[1] , 16);
pantalla.escribirCaracter(segunh[0] , 24);
pantalla.escribirCaracter(seguna[0] , 9);
pantalla.escribirCaracter(seguna[1] , 0);
pantalla.setLed(1, 0, 2, true);
pantalla.setLed(1, 0, 5, true);
delay(900);
}
Reply
- Chema on 22 febrero, 2020 at 17:51
  Es para un reloj con 4 matrices de 8×8
  Reply
  - Chema on 22 febrero, 2020 at 17:52
    Los includes:
    #include RTClib.h
    #include MatrizLed.h
    #include stdlib.h
    #include time.h
    #include Wire.h
    #include TimeLib.h
    #include DS1307RTC.h
Leo on 25 junio, 2019 at 16:36
Una pregunta, este código también sirve para configurar el DS3132?. Saludos.
Reply
- Admin on 25 junio, 2019 at 19:06
  Si te sirve.
  Nosotros hemos desarrollado otras librerías, tal vez quieras revisar el post correspondiente.
  https://www.geekfactory.mx/tutoriales/tutoriales-arduino/ds3231-el-reloj-en-tiempo-real-de-gran-precision-para-arduino/
  Saludos.
  Reply
fernando on 23 enero, 2019 at 12:51
hola, es normal que no funcione el reloj en tiempo real si no tiene bateria aunque este alimentandose el ds1307 a los 5 volts?
Reply
Anónimo on 29 septiembre, 2018 at 20:19
reloj despertador con ds1307 y display 7segmentos ?
Reply
Jared m on 2 marzo, 2018 at 1:50
Muy interesante el contenido de este blog, felicitaciones. Tengo problemas con la librería TimeAlarms.h, eh copiado el ejemplo y descargado la librería como lo indican los pasos pero no me funciona, arduino no reconoce la librería, ayuda por favor.
mensaje de error:
Arduino:1.8.4 (Windows 8.1), TD: 1.41, Tarjeta:”Arduino/Genuino Uno”
In file included from C:\Users\Jared\Pictures\peces\Ideas Proyectos\PROYECTO ACUARIO\RELOJ\RELOJ_DS1307\RELOJ_DS1307.ino:8:0:
C:\Users\Jared\Documents\Arduino\libraries\TimeAlarms/TimeAlarms.h:71:31: error: ‘timeDayOfWeek_t’ does not name a type
AlarmID_t alarmRepeat(const timeDayOfWeek_t DOW, const int H, const int M, const int S, OnTick_t onTickHandler); // as above, with day of week
^
C:\Users\Jared\Documents\Arduino\libraries\TimeAlarms/TimeAlarms.h:75:29: error: ‘timeDayOfWeek_t’ does not name a type
AlarmID_t alarmOnce(const timeDayOfWeek_t DOW, const int H, const int M, const int S, OnTick_t onTickHandler); // as above, with day of week
^
C:\Users\Jared\Pictures\peces\Ideas Proyectos\PROYECTO ACUARIO\RELOJ\RELOJ_DS1307\RELOJ_DS1307.ino: In function ‘void setup()’:
RELOJ_DS1307:15: error: ‘setTime’ was not declared in this scope
setTime(13, 59, 50, 22, 8, 16);
^
C:\Users\Jared\Pictures\peces\Ideas Proyectos\PROYECTO ACUARIO\RELOJ\RELOJ_DS1307\RELOJ_DS1307.ino: In function ‘void digitalClockDisplay()’:
RELOJ_DS1307:51: error: ‘hour’ was not declared in this scope
Serial.print(hour());
^
RELOJ_DS1307:52: error: ‘minute’ was not declared in this scope
printDigits(minute());
^
RELOJ_DS1307:53: error: ‘second’ was not declared in this scope
printDigits(second());
^
Se encontraron múltiples librerías para “TimeAlarms.h”
Usado: C:\Users\Jared\Documents\Arduino\libraries\TimeAlarms
No usado: C:\Users\Jared\Documents\Arduino\libraries\TimeAlarms-1.5.0
exit status 1
‘setTime’ was not declared in this scope
Este reporte podría tener más información con
“Mostrar salida detallada durante la compilación”
opción habilitada en Archivo -> Preferencias.
Reply
Edgar Rios on 30 octubre, 2017 at 15:31
Hola … muy buen tutorial … me gustaría saber, cual es el procedimiento para no trabajar las horas en formato de 24h, quiero usarlo en formato de 12h, es decir horas “AM” & “PM” ……….. gracias
Reply
Carlos on 29 septiembre, 2017 at 9:14
Hola, muy buena pagina con buen contenido, ya probé el código y todo perfecto con el RTC, ahora quiero acceder a el a través de un programa llamado LabView mediante el protocolo I2C, en este programa tengo que ingresar el numero del canal i2c, la dirección i2c del Tiny, los bytes que voy a leer, entre otras cosas, tienes alguna información sobre esto? Gracias de antemano.
Reply
- Jesus Ruben Santa Anna Zamudio on 29 septiembre, 2017 at 12:06
  Hola.
  Te comento que no dispongo de información para usar el DS1307 con Labview, sin embargo te deseo suerte en la búsqueda.
  Agredecemos también que te tomes el tiempo de comentar y nos da gusto que el contienido de nuestra web sea de utilidad.
  Saludos.
  Reply

← Older Comments

Trackbacks/Pingbacks

Programación de Eventos con Arduino y RTC - Geek Factory - […] En otra entrada anterior hemos tratado ya como realizar la conexión del RTC DS1307 con Arduino, así como su…

Tutorial DS1307 Tiny RTC con Arduino

Conceptos básicos.

Funcionamiento interno y registros del DS1307

Materiales necesarios.

Conexión del TinyRTC al Arduino

Ejemplo de lectura DS1307 sin librería

¿Como poner a tiempo el DS1307?

¿Como leer la fecha y hora del DS1307?

Librería de Arduino para el DS1307

Programación de un horario con Arduino

Conclusión

32 Comments

Trackbacks/Pingbacks

Submit a Comment Cancelar respuesta

Buscar en el Blog

Categorías de nuestro blog

Conócenos

Nuestra tienda

Distribuciones

Geek Factory – Tienda de Electrónica en Línea.

Tutorial DS1307 Tiny RTC con Arduino

Conceptos básicos.

Funcionamiento interno y registros del DS1307

Materiales necesarios.

Conexión del TinyRTC al Arduino

Ejemplo de lectura DS1307 sin librería

¿Como poner a tiempo el DS1307?

¿Como leer la fecha y hora del DS1307?

Librería de Arduino para el DS1307

Programación de un horario con Arduino

Conclusión

32 Comments

Trackbacks/Pingbacks

Submit a Comment Cancelar respuesta

Productos que te pueden interesar

Buscar en el Blog

Categorías de nuestro blog